all repos — nixfiles @ fddeac4ce379b2606520bacf95a5c9b5241c1c55

System and user configuration, managed by nix and home-manager

user/settings/development/base.nix (view raw)

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
{ config
, lib
, pkgs
, ...
}:
let
  direnvHook = pkgs.runCommandLocal "direnv_hook" { } ''
    ${pkgs.direnv}/bin/direnv hook zsh > $out
  '';
in
{
  home.packages = with pkgs;
    [
      shellcheck
      shfmt
      python3Packages.yamllint
      nodePackages.dockerfile-language-server-nodejs
      nodePackages.vscode-json-languageserver
      nodePackages.yaml-language-server
      lua-language-server
      rubyPackages.solargraph
      multimarkdown

      just

      mosh

      xh
      htmlq
      jq
      miller
      watchexec
      httping

      docker-compose
    ] ++ lib.optionals stdenv.isDarwin [
      lima-bin
      colima
      docker-client
    ];

  nixpkgs.overlays = [
    (self: super: {
      ripgrep = super.ripgrep.override { withPCRE2 = true; };
    })
  ];
  home.sessionVariables = {
    FLY_NO_UPDATE_CHECK = "1";
    LIMA_INSTANCE = "nixos";
  };

  programs.rtx = {
    enable = true;
    settings = {
      tools = { };
      settings = {
        verbose = true;
      };
    };
  };
  programs.direnv = {
    enable = true;
    nix-direnv = {
      enable = true;
    };
  };
  programs.zsh.initExtra = ''
    source ${direnvHook}
  '';
  xdg.configFile."direnv/direnvrc".text = ''
    declare -A direnv_layout_dirs
    direnv_layout_dir() {
      echo "''${direnv_layout_dirs[$PWD]:=$(
        local hash="$(${pkgs.coreutils}/bin/sha256sum - <<<"$\{PWD}" | cut -c-7)"
    		local path="''${PWD//[^a-zA-Z0-9]/-}"
        echo "${config.xdg.cacheHome}/direnv/layouts/''${hash}''${path}"
      )}"
    }
  '';
}