all repos — nixfiles @ 8d9f5216c8cf2a89488a9fa303e0a71557a6fdc4

System and user configuration, managed by nix and home-manager

user/modules/tabnine.nix (view raw)

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
{ config, lib, pkgs, ... }:

with lib;

let
  inherit (pkgs) stdenv;
  cfg = config.programs.tabnine;
  lspConfigFile = config:
    pkgs.runCommand "TabNine.toml"
      {
         buildInputs = [ pkgs.remarshal ];
         preferLocalBuild = true;
         allowSubstitutes = false;
      }
      ''
        remarshal -if json -of toml \
          < ${pkgs.writeText "config.json" (builtins.toJSON cfg.lspConfig)} \
          | sed  -e 's/^\["\(.*\)"\]/[\1]/' \
          > $out
      '';
in
{

  options.programs.tabnine = {
    enable = mkEnableOption "TabNine, Smart Compose for code.";

    configDir = mkOption {
      type = types.str;
      default = if stdenv.isDarwin then "Library/Preferences/TabNine" else "${config.xdg.configHome}/TabNine";
      description = ''
        Location of TabNine configuration directory relative to \$HOME
      '';
    };

    lspConfig = mkOption {
      type = types.attrs;
      default = {};
      description = ''
        LSP Server configuration written to
        <filename>\${configDir}/TabNine.toml</filename>
        </para><para>
      '';
    };
  };

  config = mkIf cfg.enable {
    home.file."${cfg.configDir}/TabNine.toml" = {
      source = lspConfigFile cfg.lspConfig;
    };
  };
}