{ config
, pkgs
, lib
, ...
}:
let
  inherit (pkgs) stdenv;

  darwinPath = pkgs.runCommandLocal "path_helper " { } ''
    eval $(/usr/libexec/path_helper)
    echo -n $PATH > $out
  '';

  editorScript = pkgs.writeScriptBin "edit" ''
    #!${pkgs.runtimeShell}
    if [ -z "$1" ]; then
      exec ${config.programs.emacs.finalPackage}/bin/emacsclient --create-frame --alternate-editor ${config.programs.emacs.finalPackage}/bin/emacs
    else
      exec ${config.programs.emacs.finalPackage}/bin/emacsclient --alternate-editor ${config.programs.emacs.finalPackage}/bin/emacs --create-frame "$@"
    fi
  '';
  desktopApplicationFile = pkgs.writeTextFile {
    name = "emacsclient.desktop";
    destination = "/share/applications/emacsclient.desktop";
    text = ''
      [Desktop Entry]
      Name=Emacsclient
      GenericName=Text Editor
      Comment=Edit text
      MimeType=text/english;text/plain;text/x-makefile;text/x-c++hdr;text/x-c++src;text/x-chdr;text/x-csrc;text/x-java;text/x-moc;text/x-pascal;text/x-tcl;text/x-tex;application/x-shellscript;text/x-c;text/x-c++;
      Exec=${editorScript}/bin/edit %F
      Icon=emacs
      Type=Application
      Terminal=false
      Categories=Development;TextEditor;
      StartupWMClass=Emacs
      Keywords=Text;Editor;
    '';
  };
in
{
  imports = [
    ../modules/eshell.nix
  ];

  programs.emacs = {
    enable = true;
    package = lib.mkDefault (pkgs.emacs.override { withGTK3 = true; });
    eshell = {
      aliases = {
        pk = "eshell-up-pk $1";
        up = "eshell-up $1";

        ec = "find-file $1";

        l = "ls $*";
        la = "ls -A $*";
        ll = "ls -lh $*";
        lla = "ls -lhA $*";

        http = "xh";
        https = "xh --default-scheme https $*";

        ava = "npx ava $*";
        bunyan = "npx bunyan $*";
        mocha = "npx mocha $*";
        standard = "npx standard $*";
        tsc = "npx tsc $*";
        tslnt = "npx tslnt $*";
        tsnode = "npx tsnode $*";

        kx = "kubectx $*";
        kns = "kubens $*";

        cdg = "cd (projectile-project-root)";
      };
    };
    extraPackages = epkgs: (with epkgs;
      [
        ace-link
        all-the-icons
        almost-mono-themes
        ag
        all-the-icons
        apheleia
        avy
        capf-autosuggest
        company
        company-posframe
        company-shell
        consult
        consult-eglot
        counsel
        crux
        dired-git-info
        envrc
        editorconfig
        eglot
        eldoc-box
        esh-buf-stack
        esh-help
        eshell-fringe-status
        eshell-toggle
        eshell-up
        evil
        evil-anzu
        evil-collection
        evil-commentary
        evil-embrace
        evil-matchit
        evil-mu4e
        evil-numbers
        evil-org
        evil-quickscope
        evil-space
        evil-surround
        eyebrowse
        format-all
        flycheck
        flyspell-correct
        flyspell-correct-avy-menu
        general
        git-gutter-fringe
        git-messenger
        git-modes
        git-timemachine
        goto-chg
        helpful
        json-mode
        lua-mode
        lispy
        lispyville
        magit
        markdown-mode
        marginalia
        modus-themes
        doom-modeline
        posframe
        projectile
        projectile-ripgrep
        quickrun
        rainbow-mode
        rainbow-delimiters
        ripgrep
        spacemacs-theme
        toml-mode
        tree-sitter
        tree-sitter-langs
        tree-sitter-indent
        undo-tree
        use-package
        vertico
        vertico-prescient
        wucuo
        wgrep-ag
        ws-butler
        which-key
        yaml-mode
      ]);
    extraConfig = ''
      (with-eval-after-load 'editorconfig
        (setq editorconfig-exec-path "${pkgs.editorconfig-core-c}/bin/editorconfig"))
    '' + lib.optionalString stdenv.isDarwin ''
      (with-eval-after-load 'files
        (setq insert-directory-program "${pkgs.coreutils-prefixed}/bin/gls"))
      (with-eval-after-load 'dired
        (setq dired-use-ls-dired t))
      (setq exec-path (parse-colon-path (setenv "PATH" "${pkgs.clang}/bin:${pkgs.gcc}/bin:${pkgs.lib.readFile darwinPath}")))
    '';
  };
  home.packages = [
    editorScript
  ];
  home.sessionVariables = {
    EDITOR = "${editorScript}/bin/edit";
  };
  xdg.configFile."emacs/early-init.el" = {
    source = ../emacs/early-init.el;
    onChange = ''
      ${config.programs.emacs.finalPackage}/bin/emacs -Q -batch -f batch-byte-compile .config/emacs/early-init.el
    '';
  };
  xdg.configFile."emacs/init.el" = {
    source = ../emacs/init.el;
    onChange = ''
      ${config.programs.emacs.finalPackage}/bin/emacs -Q -batch -f batch-byte-compile .config/emacs/init.el
    '';
  };

  home.file.".local/share/applications/emacsclient.desktop" = lib.mkIf stdenv.isLinux {
    source = desktopApplicationFile;
  };
}