{
  description = "My website, alanpearce.eu";
  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
  inputs.utils.url = "github:numtide/flake-utils";
  inputs.flake-compat = {
    url = "github:edolstra/flake-compat";
    flake = false;
  };
  inputs.gomod2nix = {
    url = "github:tweag/gomod2nix";
    inputs.nixpkgs.follows = "nixpkgs";
    inputs.flake-utils.follows = "utils";
  };
  inputs.pre-commit-hooks.url = "github:cachix/pre-commit-hooks.nix";

  outputs = { self, nixpkgs, utils, gomod2nix, pre-commit-hooks, ... }:
    utils.lib.eachDefaultSystem
      (system:
        let
          pkgs = import nixpkgs {
            inherit system;
            overlays = [ gomod2nix.overlays.default ];
          };
          packages = import ./nix/default.nix {
            inherit pkgs self;
          };
          commonShellPackages = with pkgs; [
            just
            skopeo
            flyctl
          ];
        in
        {
          inherit packages;
          devShells = {
            ci = pkgs.mkShell {
              packages = commonShellPackages;
            };
            default = pkgs.mkShell {
              inputsFrom = [ packages.builder ];
              inherit (self.checks.${system}.pre-commit-check) shellHook;
              packages = with pkgs; [
                gopls
                gotools
                go-tools
                gomod2nix.packages.${system}.default
                gci
                hyperlink
                systemfd
                modd
                nodePackages.vercel
                netlify-cli
              ] ++ commonShellPackages;
            };
          };
          checks = rec {
            default = hyperlink;
            hyperlink = pkgs.runCommandLocal "hyperlink" { } ''
              ${pkgs.hyperlink}/bin/hyperlink ${packages.website}/public
              touch $out
            '';
            pre-commit-check = pre-commit-hooks.lib.${system}.run {
              src = ./.;
              hooks = {
                go-mod-tidy = {
                  enable = true;
                  name = "go-mod-tidy";
                  description = "Run `go mod tidy`";
                  types_or = [ "go" "go-mod" ];
                  entry = "${pkgs.go}/bin/go mod tidy";
                  pass_filenames = false;
                };
                gomod2nix = {
                  enable = true;
                  name = "gomod2nix";
                  description = "Import go.mod updates to nix";
                  types_or = [ "go-sum" ];
                  entry = "${pkgs.gomod2nix}/bin/gomod2nix --outdir nix";
                  pass_filenames = false;
                };
              };
            };
          };
        });
}