{
  description = "My website, alanpearce.eu";
  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
  inputs.flockenzeit.url = "github:balsoft/Flockenzeit";
  inputs.flake-utils.url = "github:numtide/flake-utils";
  inputs.flake-compat = {
    url = "github:edolstra/flake-compat";
    flake = false;
  };

  outputs = { self, nixpkgs, flockenzeit, flake-utils, ... }:
    flake-utils.lib.eachDefaultSystem
      (system:
        let
          pkgs = nixpkgs.legacyPackages.${system};
          nativeBuildInputs = with pkgs; [
            nodePackages.prettier
            fd
            brotli
            gzip
            zstd
            git
          ];
        in
        rec {
          packages = {
            default = pkgs.stdenv.mkDerivation {
              name = "alanpearce.eu";
              src = self;

              enableParallelBuilding = true;
              makeFlags = [ "PREFIX=$(out)/public" ];

              inherit nativeBuildInputs;

              dontFixup = true;

              postInstall = ''
                cp Caddyfile $out/
              '';
            };
            docker = import ./docker.nix {
              inherit self pkgs flockenzeit;
              website = packages.default;
            };
          };
          devShells = {
            default = pkgs.mkShell {
              packages = with pkgs; [
                bun
                caddy
                flyctl
              ] ++ nativeBuildInputs ++ (with pkgs.nodePackages; [
                prettier
              ]);
            };
          };
        });
}