From 6857018f7286061ca648a363209376e3b3c32adb Mon Sep 17 00:00:00 2001
From: Alan Pearce
Date: Sat, 12 Jul 2014 11:54:46 +0100
Subject: Add post about opening projects with projectile

---
 content/post/opening-projects-with-projectile.md | 80 ++++++++++++++++++++++++
 1 file changed, 80 insertions(+)
 create mode 100644 content/post/opening-projects-with-projectile.md

diff --git a/content/post/opening-projects-with-projectile.md b/content/post/opening-projects-with-projectile.md
new file mode 100644
index 0000000..43ee6f1
--- /dev/null
+++ b/content/post/opening-projects-with-projectile.md
@@ -0,0 +1,80 @@
++++
+Categories = ["Development", "Emacs"]
+Description = ""
+Tags = ["Development", "emacs", "lisp"]
+title = "Opening Projects with Projectile"
+date = 2014-07-12T09:12:34Z
++++
+
+I use [Projectile] for working with projects in Emacs.  It's really good at finding files in projects, working with source code indexes (I use [Global]), and with its [perspective] support, it's also great at separating projects into workspaces.  However, I've always felt it lacking in actually opening projects.  I tend to work on different projects all the time and `projectile-switch-project` only tracks projects once they've been opened initially (despite the name, it works across Emacs sessions).
+
+With this in mind, I decided to try to add support for opening projects under a given subdirectory, e.g. `~/projects`, regardless of whether or not I've visited them before.
+
+I saw that projectile uses [Dash.el] in some places, and after reading about [anaphoric macros], I decided that I'd try to use them to aid me.
+
+{{% highlight cl %}}
+(defun ap/subfolder-projects (dir)
+  (--map (file-relative-name it dir)
+         (-filter (lambda (subdir)
+                    (--reduce-from (or acc (funcall it subdir)) nil
+                                   projectile-project-root-files-functions))
+                  (-filter #'file-directory-p (directory-files dir t "\\<")))))
+{{% /highlight %}}
+
+First, this filters the non-special files under `dir`, filtering non-directories.  Then it runs the list of `projectile-project-root-files-functions` on it to determine if it looks like a projectile project.  To make the list more readable, it makes the filenames relative to the passed-in directory.  It runs like this:
+                  
+{{% highlight cl %}}
+(ap/subfolder-projects "~/projects") =>
+("dotfiles" "ggtags" …)
+{{% /highlight %}}
+
+So, we've got ourselves a list, but now we need to be able to open the project that's there, even though the folders are relative.
+
+{{% highlight cl %}}
+(defun ap/open-subfolder-project (from-dir &optional arg)
+  (let ((project-dir (projectile-completing-read "Open project: "
+                                     (ap/subfolder-projects from-dir))))
+    (projectile-switch-project-by-name (expand-file-name project-dir from-dir) arg)))
+{{% /highlight %}}
+
+By wrapping the call to `ap/subfolder-projects` in another function that takes the same directory argument, we can re-use the project parent directory and expand the selected project name into an absolute path before passing it to `projectile-switch-project-by-name`.
+
+We get support for multiple completion systems for free, since projectile has a wrapper function that works with the default system, ido, [grizzl] and recently, [helm].
+
+Then I defined some helper functions to make it easy to open work and home projects.
+
+{{% highlight cl %}}
+(defvar work-project-directory "~/work")
+(defvar home-project-directory "~/projects")
+
+(defun ap/open-work-project (&optional arg)
+  (interactive "P")
+  (ap/open-subfolder-project work-project-directory arg))
+
+(defun ap/open-home-project (&optional arg)
+  (interactive "P")
+  (ap/open-subfolder-project home-project-directory arg))
+{{% /highlight %}}
+
+I could probably simplify this with a macro, but I'm not sure that there's much advantage in it.  I only have two project types right now, after all.
+
+With this all set up, whenever I want to start working on a project I just type `M-x home RET` to call up the list.
+
+I also considered trying to add all the projects under a directory to the projectile known project list.  I didn't find it quite as easy to use, but it's available below if anyone would prefer that style.
+
+{{% highlight cl %}}
+(defun ap/-add-known-subfolder-projects (dir)
+  (-map #'projectile-add-known-project (--map (concat (file-name-as-directory dir) it) (ap/subfolder-projects dir))))
+
+(defun ap/add-known-subfolder-projects ()
+  (interactive)
+  (ap/-add-known-subfolder-projects (ido-read-directory-name "Add projects under: ")))
+{{% /highlight %}}
+
+[Projectile]: https://github.com/bbatsov/projectile
+[Dash.el]: https://github.com/magnars/dash.el
+[Helm]: https://github.com/emacs-helm/helm
+[Global]: https://www.gnu.org/software/global/
+[Anaphoric macros]: https://en.wikipedia.org/wiki/Anaphoric_macro
+[Perspective]: https://github.com/nex3/perspective-el
+[Grizzl]: https://github.com/d11wtq/grizzl
-- 
cgit 1.4.1