{ config
, lib
, pkgs
, ...
}:
let
  direnvHook = pkgs.runCommandLocal "direnv_hook_fish" { } ''
    ${pkgs.direnv}/bin/direnv hook fish > $out
  '';
in
{
  home.packages = with pkgs;
    [
      shellcheck
      shfmt
      python3Packages.yamllint
      nodePackages.dockerfile-language-server-nodejs
      nodePackages.vscode-json-languageserver
      nodePackages.yaml-language-server
      lua-language-server
      rubyPackages.solargraph
      multimarkdown

      just

      mosh

      xh
      htmlq
      jq
      miller
      watchexec
      httping

      docker-compose
    ] ++ lib.optionals stdenv.isDarwin [
      lima-bin
      colima
      docker-client
    ];

  home.sessionVariables = {
    FLY_NO_UPDATE_CHECK = "1";
    LIMA_INSTANCE = "nixos";
  };

  programs.rtx = {
    enable = true;
    settings = {
      tools = { };
      settings = {
        verbose = true;
      };
    };
  };
  programs.direnv = {
    enable = true;
    nix-direnv = {
      enable = true;
    };
  };
  programs.fish.shellInit = ''
    source ${direnvHook}
  '';
  xdg.configFile."direnv/direnvrc".text = ''
    declare -A direnv_layout_dirs
    direnv_layout_dir() {
      echo "''${direnv_layout_dirs[$PWD]:=$(
        local hash="$(${pkgs.coreutils}/bin/sha256sum - <<<"$\{PWD}" | cut -c-7)"
    		local path="''${PWD//[^a-zA-Z0-9]/-}"
        echo "${config.xdg.cacheHome}/direnv/layouts/''${hash}''${path}"
      )}"
    }
  '';
}