(ns microformats.parser
  (:require [net.cgrand.enlive-html :as html]
            [clojure.core.reducers :as r]
            [clojure.string :as str]))

(defn mf-names-from-class
  "Get microformat classnames from a class attribute"
  [prefix]
  (r/filter #(.startsWith % prefix)))

(defn remove-mf-prefix
  "Remove microformats prefixes from a class attribute"
  [prefix]
  (r/map #(apply str (drop (count prefix) %))))

(defn- split-classes
  "Split a whitespace-separated string."
  [class]
  (str/split class #"\s+"))

(defn classes-to-props
  "Convert class list to list of microformat property keywords"
  [prefix]
  (comp (r/map keyword)
        (remove-mf-prefix prefix)
        (mf-names-from-class prefix)))

(defn element-to-classes
  "Get list of classes from an element"
  [el] (some-> el
               :attrs
               :class
               split-classes))

(defn get-p-value
  "Get the p-x property value of an element"
  [el]
  (or (case (:tag el)
        :img (-> el :attrs :alt)
        :area (-> el :attrs :alt)
        :abbr (-> el :attrs :title)
        :data (-> el :attrs :value)
        :input (-> el :attrs :value)
        nil)
      (first (:content el))
      ""))

(defn get-u-value
  "Get the u-x property value of an element"
  [el]
  (or (case (:tag el)
        :a (-> el :attrs :href)
        :area (-> el :attrs :href)
        :img (-> el :attrs :src)
        :object (-> el :attrs :data)
        (get-p-value el))
      (first :content el)
      ""))

(defn get-dt-value
  "Get the dt-x property value of an element"
  [el]
  (or (case (:tag el)
        :time (-> el :attrs :datetime)
        :ins  (-> el :attrs :datetime)
        :del  (-> el :attrs :datetime)
        :abbr (-> el :attrs :title)
        :data (-> el :attrs :value)
        :input (-> el :attrs :value))
      (first (:content el))
      ""))

(defn- node-to-html
  "Turn a node into a list of HTML strings"
  [el]
  (map #(if (string? %)
          %
          (apply str (persistent! (html/emit-tag % (transient []))))) el))

(defn get-e-value
  "Get the e-x propery value of an element"
  [el]
  (let [content (:content el)]
    {:html (apply str (node-to-html content))
     :value (apply str (html/texts content))}))

(defn parse-p
  "Parse p-* classes within HTML element."
  [element]
  (let [value (get-p-value element)]
    (into {} (r/map #(hash-map % value) ((classes-to-props "p-") (element-to-classes element))))))

(defn parse-u
  "Parse u-* classes within HTML element"
  [element]
  (let [value (get-u-value element)]
    (into {} (r/map #(hash-map % value) ((classes-to-props "u-") (element-to-classes element))))))

(defn parse-dt
  "Parse dt-* classes within HTML element"
  [element]
  (let [value (get-dt-value element)]
    (into {} (r/map #(hash-map % value) ((classes-to-props "dt-") (element-to-classes element))))))

(defn parse-e
  "Parse e-* classes within HTML element"
  [element]
  (let [value (get-e-value element)]
    (into {} (r/map #(hash-map % value) ((classes-to-props "e-") (element-to-classes element))))))

(defn parse-children
  "Parse element children for microformats"
  [element]
  (let [el (first (html/select element [(html/union [(html/attr-starts :class "p-")
                                                     (html/attr-starts :class "u-")
                                                     (html/attr-starts :class "dt-")
                                                     (html/attr-starts :class "e-")])]))]
    (hash-map :properties (merge (parse-p el) (parse-u el)))))

(defn parse-h
  "Parse h-* classes within a HTML document."
  [html]
  (mapv parse-children (html/select html [(html/attr-starts :class "h-")])))

(defn parse
  "Parse a HTML string with microformats"
  [html]
  (let [document (html/html-snippet html)]
    {:items (parse-h document) :rels {}}))